اتصال دو آردوینو با پروتکل I2C: آموزش + کدنویسی

    ()Wire.write:

کاربرد: برای نوشتن داده در Master و ‌یا Slave؛ اگر Slave بخواهد در Master چیزی بنویسد، تابع ()Wire.RequestFrom در Master فراخوانی شده است.  اگر Master بخواهد در Slave چیزی بنویسد، ابتدا تابع ()Wire.beginTransmission فراخوانی می‌شود، سپس تابع ()Wire.write و پس از آن ()Wire.endTransmission خود تابع ()Wire.write می‌تواند به صورت‌های زیر نوشته شود. (Wire.write(value: مقدار value همان بایتی است که قرار است نوشته شود. (Wire.write(string: رشته‌ای از بایت‌های متوالی که ارسال و نوشته می‌شوند. (Wire.write(data, length: آرایه‌ای از داده‌ها به صورت بایت به بایت و length تعداد این بایت‌ها را مشخص می‌کند.

 (Wire.beginTransmission(address:

کاربرد: این تابع ارتباط I2C با Slave که برای اتصال دو آردوینو، آدرس آن مشخص شده است را آغاز خواهد کرد.

پس از آغاز ارتباط دیتایی که قرار است مبادله شود در صف ارسال قرار می‌گیرد و تابع ()write مورد استفاده قرار خواهد گرفت. در انتهای تبادل نیز تابع ()endTransmission فراخوانی خواهد شد. آدرس نیز همان‌طور که قبل‌تر هم گفتیم‌ یک آدرس ۷ بیتی است.

     ()Wire.endTransmission:

کاربرد: این تابع ارتباطی را که قبل‌تر توسط ()beginTransmission شروع شده است را خاتمه خواهد داد.

    ()Wire.onRequest:

کاربرد: کاربرد این تابع در اتصال دو آردوینو زمانی است که Master بخواهد از‌ یکی از Slave‌ها با استفاده از تابع ()Wire.requestFrom درخواست داده کند. Slave مذکور با استفاده از تابع ()Wire.write داده را ارسال خواهد نمود.

    ()Wire.onReceive:

کاربرد در اتصال دو آردوینو: زمانی که Slave از Master داده دریافت کرده باشد، فراخوانی می‌شود. برای خواندن داده‌ی دریافتی نیز از تابع ()Wire.read استفاده می‌شود.

    (Wire.requestFrom(address,quantity:

این تابع در Master و برای گرفتن داده از ‌یک Slave استفاده می‌شود. پس از دریافت داده‌ی مورد نظر با استفاده از تابع ()Wire.read خوانده خواهد شد. آدرس همان آدرس ۷ بیتی Slave مورد خطاب است و quantity تعداد بایت‌های مورد درخواست است.

قطعه‌های لازم برای اتصال دو آردوینو

•     دو عدد بورد Arduino Uno

•     دو عدد LCD 16×2

•     چهار عدد پتانسیومتر 10K

•     برد بورد

•     سیم رابط

کدنویسی برای اتصال دو آردوینو

برای درک هرچه بهتر اتصال دو آردوینو با استفاده از هر 2 بخش Master و Slave، کافی است که این کد را در پروژه خود اجرا کنید:

Master Arduino Programming
//I2C MASTER CODE 
//I2C Communication between Two Arduino
//Circuit Digest
//Pramoth.T
#include<Wire.h>                             //Library for I2C Communication functions
#include<LiquidCrystal.h>                    //Library for LCD display function
LiquidCrystal lcd(2, 7, 8, 9, 10, 11);       //Define LCD Module Pins (RS,EN,D4,D5,D6,D7)
 void setup() 
{ 
  lcd.begin(16,2);                           //Initilize LCD display
  lcd.setCursor(0,0);                        //Sets Cursor at first line of Display 
  lcd.print("Circuit Digest");               //Prints CIRCUIT DIGEST in LCD 
  lcd.setCursor(0,1);                        //Sets Cursor at second line of Display
  lcd.print("I2C 2 ARDUINO");                //Prints I2C ARDUINO in LCD
  delay(5000);                               //Delay for 5 seconds
  lcd.clear();                               //Clears LCD display
  Serial.begin(9600);                        //Begins Serial Communication at 9600 baud rate
  Wire.begin();                              //Begins I2C communication at pin (A4,A5)
}
void loop()
{
    Wire.requestFrom(8,1);                           // request 1 byte from slave arduino (8)
    byte MasterReceive = Wire.read();                // receive a byte from the slave arduino and store in MasterReceive
    int potvalue = analogRead(A0);                   // Reads analog value from POT (0-5V)
    byte MasterSend = map(potvalue,0,1023,0,127);    //Convert digital value (0 to 1023) to (0 to 127)
     
    Wire.beginTransmission(8);                       // start transmit to slave arduino (8)
    Wire.write(MasterSend);                          // sends one byte converted POT value to slave
    Wire.endTransmission();                          // stop transmitting
    lcd.setCursor(0,0);                              //Sets Currsor at line one of LCD
    lcd.print(">>  Master  <<");                     //Prints >> Master << at LCD
    lcd.setCursor(0,1);                              //Sets Cursor at line two of LCD
    lcd.print("SlaveVal:");                          //Prints SlaveVal: in LCD
    lcd.print(MasterReceive);                        //Prints MasterReceive in LCD received from Slave
    Serial.println("Master Received From Slave");    //Prints in Serial Monitor 
    Serial.println(MasterReceive);
    delay(500);                                     
    lcd.clear();
  
}     
Slave Arduino Programming
//I2C SLAVE CODE
//I2C Communication between Two Arduino
//CircuitDigest
//Pramoth.T
#include<Wire.h>                          //Library for I2C Communication functions
#include<LiquidCrystal.h>                 //Library for LCD display function
LiquidCrystal lcd(2, 7, 8, 9, 10, 11);    //Define LCD Module Pins (RS,EN,D4,D5,D6,D7)
byte SlaveReceived = 0;
void setup() 
{
  lcd.begin(16,2);                        //Initilize LCD display
  lcd.setCursor(0,0);                     //Sets Cursor at first line of Display 
  lcd.print("Circuit Digest");            //Prints CIRCUIT DIGEST in LCD 
  lcd.setCursor(0,1);                     //Sets Cursor at second line of Display
  lcd.print("I2C 2 ARDUINO");             //Prints I2C ARDUINO in LCD
  delay(5000);                            //Delay for 5 seconds
  lcd.clear();                            //Clears LCD display
  Serial.begin(9600);                     //Begins Serial Communication at 9600 baud rate
  Wire.begin(8);                          //Begins I2C communication with Slave Address as 8 at pin (A4,A5)
  Wire.onReceive(receiveEvent);           //Function call when Slave receives value from master
  Wire.onRequest(requestEvent);           //Function call when Master request value from Slave
} 
void loop(void) 
{
  lcd.setCursor(0,0);                              //Sets Currsor at line one of LCD
  lcd.print(">>  Slave  <<");                      //Prints >> Slave << at LCD
  lcd.setCursor(0,1);                              //Sets Cursor at line two of LCD
  lcd.print("MasterVal:");                         //Prints MasterVal: in LCD
  lcd.print(SlaveReceived);                        //Prints SlaveReceived value in LCD received from Master
  Serial.println("Slave Received From Master:");   //Prints in Serial Monitor 
  Serial.println(SlaveReceived); 
  delay(500);
  lcd.clear();
  
}
void receiveEvent (int howMany)                    //This Function is called when Slave receives value from master
{
   SlaveReceived = Wire.read();                    //Used to read value received from master and store in variable SlaveReceived
}
void requestEvent()                                //This Function is called when Master wants value from slave
{
  int potvalue = analogRead(A0);                   // Reads analog value from POT (0-5V)
  byte SlaveSend = map(potvalue,0,1023,0,127);    // Convert potvalue digital value (0 to 1023) to (0 to 127)
  Wire.write(SlaveSend);                          // sends one byte converted POT value to master
}

سخن پایانی

آردوینو، یک قطعه الکترونیکی تک‌بردی است که معمولاً برای هدایت سنسورها و تغییر اندازه در موتورها و سایر گجت‌های مورد استفاده قرار می‌گیرد. امکان اتصال دو آردوینو با استفاده از پروتکل I2C امکان و اجرای چندین کد اختصاصی امکان‌پذیر است. در این مقاله به نحوه اتصال دو آردوینو پرداختیم و انواع قطعات مورد نیاز برای این کار را معرفی کردیم.

شما می‌توانید با استفاده از خدمات و قابلیت‌های فروشگاه آنلاین جم ترونیک تمامی قطعات و بردهای مورد نیاز آردوینو را خریداری کنید. ضمناً وبلاگ جم ترونیک، امکان آموزش آنلاین و ساده تمامی پروژه‌های مبتنی بر گجت‌های الکترونیکی را در اختیار علاقه‌مندان قرار داده است.

نویز برق یکی از مشکلات رایج در مدارهای الکترونیکی است که می‌تواند به شکل صدای اضافی در سیستم‌های صوتی، اختلال در عملکرد سنسورها، نوسان سیگنال، خطا در تجهیزات دیجیتال یا حتی عملکرد نامنظم یک…